build.gradle

buildscript {
    repositories {
        maven { url = 'https://maven.minecraftforge.net' }
        maven { url = 'https://repo.spongepowered.org/repository/maven-public/' }
        mavenCentral()
    }
    dependencies {
        classpath group: 'net.minecraftforge.gradle', name: 'ForgeGradle', version: '5.1.+', changing: true
        classpath group: 'org.spongepowered', name: 'mixingradle', version: '0.7-SNAPSHOT'
    }
}
plugins {
    id 'eclipse'
    id 'maven-publish'
}
apply plugin: 'net.minecraftforge.gradle'
apply plugin: 'org.spongepowered.mixin'

version = "${mod_version}-mc${mc_version}"
group = 'insane96mcp.customfluidmixin' // http://maven.apache.org/guides/mini/guide-naming-conventions.html
archivesBaseName = 'CustomFluidMixin'

java.toolchain.languageVersion = JavaLanguageVersion.of(17)

println "Java: ${System.getProperty 'java.version'}, JVM: ${System.getProperty 'java.vm.version'} (${System.getProperty 'java.vendor'}), Arch: ${System.getProperty 'os.arch'}"
minecraft {
    mappings channel: 'official', version: "${mc_version}"

    // accessTransformer = file('src/main/resources/META-INF/accesstransformer.cfg') // Currently, this location cannot be changed from the default.

    runs {
        client {
            workingDirectory project.file('run')

            property 'forge.logging.markers', 'REGISTRIES'

            args '-mixin.config=customfluidmixin.mixins.json'

            property 'forge.logging.console.level', 'debug'

            property 'forge.enabledGameTestNamespaces', 'customfluidmixin'

            mods {
                customfluidmixin {
                    source sourceSets.main
                }
            }
        }

        server {
            workingDirectory project.file('run')

            property 'forge.logging.markers', 'REGISTRIES'

            property 'forge.logging.console.level', 'debug'

            args '-mixin.config=customfluidmixin.mixins.json'

            property 'forge.enabledGameTestNamespaces', 'customfluidmixin'

            mods {
                customfluidmixin {
                    source sourceSets.main
                }
            }
        }
    }
}

sourceSets.main.resources { srcDir 'src/generated/resources' }

repositories {
    flatDir {
        dir 'libs'
    }
    maven {
        // location of the maven that hosts JEI files
        name = "Progwml6 maven"
        url = "https://dvs1.progwml6.com/files/maven/"
    }
    maven {
        // location of a maven mirror for JEI files, as a fallback
        name = "ModMaven"
        url = "https://modmaven.dev"
    }
}

mixin {
    add sourceSets.main, "customfluidmixin.refmap.json"
}

dependencies {
    minecraft "net.minecraftforge:forge:${mc_version}-${forge_version}"

    annotationProcessor "org.spongepowered:mixin:${mixin_version}:processor"

    implementation fg.deobf("blank:InsaneLib:${lib_version}-mc${mc_version}")

  // compile against the JEI API but do not include it at runtime
  compileOnly(fg.deobf("mezz.jei:jei-${mc_version}-common-api:${jei_version}"))
  compileOnly(fg.deobf("mezz.jei:jei-${mc_version}-forge-api:${jei_version}"))
  // at runtime, use the full JEI jar for Forge
  runtimeOnly(fg.deobf("mezz.jei:jei-${mc_version}-forge:${jei_version}"))
}

jar {
    manifest {
        attributes([
                "Specification-Title"     : "customfluidmixin",
                "Specification-Vendor"    : "Insane96MCP",
                "Specification-Version"   : "1", // We are version 1 of ourselves
                "Implementation-Title"    : project.name,
                "Implementation-Version"  : project.jar.archiveVersion,
                "Implementation-Vendor"   : "Insane96MCP",
                "Implementation-Timestamp": new Date().format("yyyy-MM-dd'T'HH:mm:ssZ"),
                "MixinConfigs": "customfluidmixin.mixins.json"
        ])
    }
}

jar.finalizedBy('reobfJar')
jar.finalizedBy('zipExampleDataPack')

tasks.register('zipExampleDataPack', Zip) {
    from file("src/main/resources/ExampleDataPack/")
    archiveFileName = "ExampleDataPack-${mod_version}.zip"
    destinationDirectory = file("build/libs/")
}