015.md

Shaggy Clay Cobra

High

Unable to end an successful auction

Summary

The wrong check for Auction contract address in Pool contract can cause the auction unable to be ended successfully

Root Cause

• The function Pool::transferReserveToAuction() checks if caller is the Auction contract of the current period.
• However, in the function Pool::startAuction(), the auction is started with the current period fetched from Bond token contract. And at the end of the function, the Pool contract calls to Bond contract to increase bond token period bondToken.increaseIndexedAssetPeriod(sharesPerToken). This call will cause the call bondToken.globalPool() in the function Pool::transferReserveToAuction() to return the new token period, which is different from the period that auction is started. Obviously, the auction for this period is not yet created, and the check require(msg.sender == auctionAddress, CallerIsNotAuction()) will revert.

  function startAuction() external whenNotPaused() {
    // Check if distribution period has passed
    require(lastDistribution + distributionPeriod < block.timestamp, DistributionPeriodNotPassed());

    // Check if auction period hasn't passed
    require(lastDistribution + distributionPeriod + auctionPeriod >= block.timestamp, AuctionPeriodPassed());

    // Check if auction for current period has already started
@>    (uint256 currentPeriod,) = bondToken.globalPool();
    require(auctions[currentPeriod] == address(0), AuctionAlreadyStarted());

    uint8 bondDecimals = bondToken.decimals();
    uint8 sharesDecimals = bondToken.SHARES_DECIMALS();
    uint8 maxDecimals = bondDecimals > sharesDecimals ? bondDecimals : sharesDecimals;

    uint256 normalizedTotalSupply = bondToken.totalSupply().normalizeAmount(bondDecimals, maxDecimals);
    uint256 normalizedShares = sharesPerToken.normalizeAmount(sharesDecimals, maxDecimals);

    // Calculate the coupon amount to distribute
    uint256 couponAmountToDistribute = (normalizedTotalSupply * normalizedShares)
        .toBaseUnit(maxDecimals * 2 - IERC20(couponToken).safeDecimals());

@>    auctions[currentPeriod] = Utils.deploy(
      address(new Auction()),
      abi.encodeWithSelector(
        Auction.initialize.selector,
        address(couponToken),
        address(reserveToken),
        couponAmountToDistribute,
        block.timestamp + auctionPeriod,
        1000,
        address(this),
        poolSaleLimit
      )
    );

    // Increase the bond token period
@>    bondToken.increaseIndexedAssetPeriod(sharesPerToken);

    // Update last distribution time
    lastDistribution = block.timestamp;
  }

  function transferReserveToAuction(uint256 amount) external virtual {
@>    (uint256 currentPeriod, ) = bondToken.globalPool();
    address auctionAddress = auctions[currentPeriod];
    require(msg.sender == auctionAddress, CallerIsNotAuction());
    
    IERC20(reserveToken).safeTransfer(msg.sender, amount);
  }

• From the above points, the function Auction::endAuction() will be unable to end with SUCCEEDED state because it will revert when call Pool::transferReserveToAuction()

  function endAuction() external auctionExpired whenNotPaused {
    if (state != State.BIDDING) revert AuctionAlreadyEnded();

    if (currentCouponAmount < totalBuyCouponAmount) {
      state = State.FAILED_UNDERSOLD;
    } else if (totalSellReserveAmount >= (IERC20(sellReserveToken).balanceOf(pool) * poolSaleLimit) / 100) {
        state = State.FAILED_POOL_SALE_LIMIT;
    } else {
      state = State.SUCCEEDED;
@>      Pool(pool).transferReserveToAuction(totalSellReserveAmount);
      IERC20(buyCouponToken).safeTransfer(beneficiary, IERC20(buyCouponToken).balanceOf(address(this)));
    }

Internal Pre-conditions

No response

External Pre-conditions

No response

Attack Path

1. An auction starts
2. Bidding happens
3. Auction period passes and the auction succeed.
4. Call Auction::endAuction() reverts and funds can not be settled

Impact

• Unable to end auction.
• Bid funds lost in the Auction contract

PoC

No response

Mitigation

  function transferReserveToAuction(uint256 amount) external virtual {
    (uint256 currentPeriod, ) = bondToken.globalPool();
-    address auctionAddress = auctions[currentPeriod];
+    address auctionAddress = auctions[currentPeriod - 1];
    require(msg.sender == auctionAddress, CallerIsNotAuction());
    
    IERC20(reserveToken).safeTransfer(msg.sender, amount);
  }