ghostty: add module

Author: HeitorAugustoLN

modules/modules.nix

@@ -1,13 +1,13 @@
-{ pkgs
+{ pkgs,
 
 # Note, this should be "the standard library" + HM extensions.
-, lib
+lib,
 
 # Whether to enable module type checking.
-, check ? true
+check ? true,
 
-  # If disabled, the pkgs attribute passed to this function is used instead.
-, useNixpkgsModule ? true }:
+# If disabled, the pkgs attribute passed to this function is used instead.
+useNixpkgsModule ? true, }:
 
 with lib;
 
@@ -104,6 +104,7 @@ let
     ./programs/getmail.nix
     ./programs/gh.nix
     ./programs/gh-dash.nix
+    ./programs/ghostty.nix
     ./programs/git-cliff.nix
     ./programs/git-credential-oauth.nix
     ./programs/git.nix

modules/programs/ghostty.nix

@@ -0,0 +1,38 @@
+{ config, lib, pkgs, ... }:
+let
+  cfg = config.programs.ghostty;
+  keyValue = pkgs.formats.keyValue {
+    mkKeyValue = lib.generators.mkKeyValueDefault { } " = ";
+  };
+in {
+  meta.maintainers = [ lib.maintainers.HeitorAugustoLN ];
+
+  options.programs.ghostty = {
+    enable = lib.mkEnableOption "ghostty";
+    package = lib.mkPackageOption pkgs "ghostty" { };
+
+    settings = lib.mkOption {
+      inherit (keyValue) type;
+      default = { };
+      example = lib.literalExpression ''
+        {
+          theme = "catppuccin-mocha";
+          font-size = 10;
+        }
+      '';
+      description = ''
+        Configuration written to $XDG_CONFIG_HOME/ghostty/config.
+
+        See https://ghostty.org/docs/config/reference for more information.
+      '';
+    };
+  };
+
+  config = lib.mkIf cfg.enable {
+    home.packages = [ cfg.package ];
+
+    xdg.configFile."ghostty/config" = lib.mkIf (cfg.settings != { }) {
+      source = keyValue.generate "ghostty-config" cfg.settings;
+    };
+  };
+}