[LLHD] Mem2Reg crash on reasonable input

[fabianschuiki]

The following crashes circt-opt --llhd-mem2reg:

module {
  hw.module @Foo(in %a : i1, in %b : i32, out x : i32) {
    %0 = llhd.constant_time <0ns, 0d, 1e>
    %c0_i32 = hw.constant 0 : i32
    %c42_i32 = hw.constant 42 : i32
    %false = hw.constant false
    %a_0 = llhd.sig name "a" %false : i1
    %b_1 = llhd.sig name "b" %c0_i32 : i32
    %x = llhd.sig %c0_i32 : i32
    %1 = llhd.prb %b_1 : !hw.inout<i32>
    %2 = llhd.prb %x : !hw.inout<i32>
    %3 = llhd.prb %a_0 : !hw.inout<i1>
    llhd.process {
      cf.br ^bb1
    ^bb1:  // 2 preds: ^bb0, ^bb3
      %5 = llhd.prb %b_1 : !hw.inout<i32>
      llhd.drv %x, %5 after %0 : !hw.inout<i32>
      %6 = llhd.prb %a_0 : !hw.inout<i1>
      cf.cond_br %6, ^bb2, ^bb3
    ^bb2:  // pred: ^bb1
      %7 = llhd.prb %x : !hw.inout<i32>
      %8 = comb.add %7, %c42_i32 : i32
      llhd.drv %x, %8 after %0 : !hw.inout<i32>
      cf.br ^bb3
    ^bb3:  // 2 preds: ^bb1, ^bb2
      %9 = llhd.prb %x : !hw.inout<i32>
      func.call @printikus(%9) : (i32) -> ()
      llhd.wait (%1, %2, %3 : i32, i32, i1), ^bb1
    }
    llhd.drv %a_0, %a after %0 : !hw.inout<i1>
    llhd.drv %b_1, %b after %0 : !hw.inout<i32>
    %4 = llhd.prb %x : !hw.inout<i32>
    hw.output %4 : i32
  }
  func.func private @printikus(%arg0: i32) {
    return
  }
}

[fabianschuiki]

Reduced failing case:

hw.module @Foo() {
  %0 = llhd.constant_time <0ns, 0d, 1e>
  %c0_i42 = hw.constant 0 : i42
  %x = llhd.sig %c0_i42 : i42
  %y = llhd.sig %c0_i42 : i42
  llhd.process {
    %1 = llhd.prb %x : !hw.inout<i42>
    llhd.drv %y, %1 after %0 : !hw.inout<i42>
    %2 = llhd.prb %y : !hw.inout<i42>
    func.call @use_i42(%2) : (i42) -> ()
    llhd.halt
  }
}
func.func private @use_i42(%arg0: i42)