-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathCRC32.cob
206 lines (164 loc) · 6.36 KB
/
CRC32.cob
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
*============================ CRC32 =============================*
* Authors: Brian D Pead
*
* Description: Subroutine to calculate a CRC-32 checksum on the
* specified input.
*
* License: MIT
*
* Date Version Description
* ---- ------- -----------
* 2020-02-08 1.0 First release
*================================================================*
IDENTIFICATION DIVISION.
*========================
PROGRAM-ID. CRC32.
ENVIRONMENT DIVISION.
*=====================
CONFIGURATION SECTION.
*----------------------
SOURCE-COMPUTER.
IBM-Z15.
* IBM-Z15 DEBUGGING MODE.
INPUT-OUTPUT SECTION.
*---------------------
FILE-CONTROL.
/
DATA DIVISION.
*==============
FILE SECTION.
*-------------
WORKING-STORAGE SECTION.
*------------------------
01 W-CHECKSUM-SHIFT PIC 9(09) COMP.
01 W-BITWISE-RESULT PIC 9(09) COMP.
01 W-BITWISE-PROG PIC X(08) VALUE 'BITWISE'.
01 FILLER PIC X(01) VALUE 'Y'.
88 W-FIRST-CALL VALUE 'Y'.
88 W-NOT-FIRST-CALL VALUE 'N'.
01 W-COMPILED-DATE.
05 W-COMPILED-DATE-YYYY
PIC X(04).
05 W-COMPILED-DATE-MM PIC X(02).
05 W-COMPILED-DATE-DD PIC X(02).
05 W-COMPILED-TIME-HH PIC X(02).
05 W-COMPILED-TIME-MM PIC X(02).
05 W-COMPILED-TIME-SS PIC X(02).
05 FILLER PIC X(07).
01 W-HIGH-VALUES-X PIC X(04) VALUE HIGH-VALUES.
01 W-HIGH-VALUES-BIN REDEFINES W-HIGH-VALUES-X
PIC 9(09) COMP.
01 W-INPUT-1 PIC 9(09) COMP.
01 W-INPUT-1-BYTES REDEFINES W-INPUT-1.
05 W-INPUT-1-1-3 PIC X(03).
05 W-INPUT-1-4 PIC X(01).
01 W-INPUT-2 PIC 9(09) COMP.
01 W-INPUT-2-BYTES REDEFINES W-INPUT-2.
05 W-INPUT-2-1-3 PIC X(03).
05 W-INPUT-2-4 PIC X(01).
01 W-SUB-1 PIC S9(04) COMP.
01 FILLER REDEFINES W-SUB-1.
05 FILLER PIC X(01) VALUE X'00'.
05 W-SUB-1-2 PIC X(01).
01 W-SUB-2 PIC S9(04) COMP.
01 FILLER REDEFINES W-SUB-2.
05 FILLER PIC X(01) VALUE X'00'.
05 W-SUB-2-2 PIC X(01).
01 W-BITWISE-PARAMETER. COPY BITWISEL.
COPY CRC32W.
/
LINKAGE SECTION.
*----------------
01 L-PARAMETER. COPY CRC32L.
01 L-BUFFER.
05 L-BUFFER-BYTE PIC X(01) OCCURS 32768
INDEXED L-DX.
/
PROCEDURE DIVISION USING L-PARAMETER.
*==================
MAIN.
*-----
PERFORM SUB-1000-START-UP THRU SUB-1000-EXIT
PERFORM SUB-2000-PROCESS THRU SUB-2000-EXIT
VARYING L-DX FROM 1 BY 1
UNTIL L-DX > CRC-BUFFER-LEN
IF CRC-STAGE-START-END
OR CRC-STAGE-END
PERFORM SUB-3000-COMPLEMENT THRU SUB-3000-EXIT
END-IF
.
MAIN-EXIT.
GOBACK.
/
SUB-1000-START-UP.
*------------------
IF CRC-STAGE-START-END
OR CRC-STAGE-START
MOVE W-HIGH-VALUES-BIN
TO CRC-CHECKSUM
END-IF
SET ADDRESS OF L-BUFFER
TO CRC-BUFFER-PTR
SET BW-OPERATION-XOR TO TRUE
MOVE 4 TO BW-INPUT-LEN
SET BW-OUTPUT-PTR TO ADDRESS OF W-BITWISE-RESULT
IF W-NOT-FIRST-CALL
GO TO SUB-1000-EXIT
END-IF
SET W-NOT-FIRST-CALL TO TRUE
MOVE FUNCTION WHEN-COMPILED
TO W-COMPILED-DATE
DISPLAY 'CRC32 compiled on '
W-COMPILED-DATE-YYYY '/'
W-COMPILED-DATE-MM '/'
W-COMPILED-DATE-DD ' at '
W-COMPILED-TIME-HH ':'
W-COMPILED-TIME-MM ':'
W-COMPILED-TIME-SS
.
SUB-1000-EXIT.
EXIT.
/
SUB-2000-PROCESS.
*-----------------
**** SHIFT CRC 8 BITS RIGHT:
COMPUTE W-CHECKSUM-SHIFT
= CRC-CHECKSUM / 256
**** USE LAST BYTE OF CRC:
MOVE CRC-CHECKSUM TO W-INPUT-1
MOVE LOW-VALUES TO W-INPUT-1-1-3
**** NEXT BYTE OF INPUT:
MOVE 0 TO W-INPUT-2
MOVE L-BUFFER-BYTE(L-DX)
TO W-INPUT-2-4
**** XOR LAST BYTE OF CRC AND NEXT BYTE OF INPUT:
SET BW-INPUT-1-PTR TO ADDRESS OF W-INPUT-1
SET BW-INPUT-2-PTR TO ADDRESS OF W-INPUT-2
PERFORM SUB-9100-CALL-BITWISE THRU SUB-9100-EXIT
**** XOR TABLE ENTRY AND CRC>>8:
SET BW-INPUT-1-PTR TO ADDRESS OF
W-CRC32-ENTRY(W-BITWISE-RESULT + 1)
SET BW-INPUT-2-PTR TO ADDRESS OF W-CHECKSUM-SHIFT
PERFORM SUB-9100-CALL-BITWISE THRU SUB-9100-EXIT
MOVE W-BITWISE-RESULT TO CRC-CHECKSUM
.
SUB-2000-EXIT.
EXIT.
/
SUB-3000-COMPLEMENT.
*--------------------
**** BITWISE COMPLEMENT (I.E. BITWISE NOT):
SET BW-INPUT-1-PTR TO ADDRESS OF CRC-CHECKSUM
SET BW-INPUT-2-PTR TO ADDRESS OF W-HIGH-VALUES-X
PERFORM SUB-9100-CALL-BITWISE THRU SUB-9100-EXIT
MOVE W-BITWISE-RESULT TO CRC-CHECKSUM
.
SUB-3000-EXIT.
EXIT.
/
SUB-9100-CALL-BITWISE.
*----------------------
CALL W-BITWISE-PROG USING W-BITWISE-PARAMETER
.
SUB-9100-EXIT.
EXIT.