build.gradle

apply plugin: 'java'
apply plugin: 'eclipse'
apply plugin: 'maven'
apply plugin: 'signing'

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives javadocJar, sourcesJar
}

signing {
    sign configurations.archives
}

sourceCompatibility = 1.7
targetCompatibility = 1.7

group = "io.interact"
archivesBaseName = "sqs-dropwizard"
version = applicationVersion

uploadArchives {
    repositories {
      mavenDeployer {
        beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }
  
        repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
          authentication(userName: ossrhUsername, password: ossrhPassword)
        }
  
        snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
          authentication(userName: ossrhUsername, password: ossrhPassword)
        }
  
        pom.project {
          name 'sqs-dropwizard'
          packaging 'jar'
          description 'aws-dropwizard is a utility library that integrates the Amazon SQS and SNS offerings with the Dropwizard REST framework. It contains convenience classes for sending messages to - and receiving from - SQS queues while being managed by the Dropwizard framework.'
          url 'https://github.com/bascan/sqs-dropwizard'
  
          scm {
            connection 'scm:git:https://github.com/bascan/sqs-dropwizard.git'
            developerConnection 'scm:git:https://github.com/bascan/sqs-dropwizard.git'
            url 'https://github.com/bascan/sqs-dropwizard.git'
          }
  
          licenses {
            license {
              name 'The Apache License, Version 2.0'
              url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
            }
          }
  
          developers {
            developer {
              id 'bascan'
              name 'Bas Cancrinus'
            }
            
            developer {
              id 'plevie'
              name 'Patrick Levie'
            }
          }
        }
      }
    }
  }

repositories {
    mavenCentral()
}

buildscript {
    repositories {
        mavenLocal()
        mavenCentral()
    }
}

dependencies {
    compile 'com.amazonaws:aws-java-sdk-sns:1.11.212'
    compile 'com.amazonaws:aws-java-sdk-sqs:1.11.212'
    compile "io.dropwizard:dropwizard-core:${dropwizardVersion}"
    compile "io.dropwizard:dropwizard-logging:${dropwizardVersion}"
    compile "io.dropwizard:dropwizard-validation:${dropwizardVersion}"
    compile "io.dropwizard:dropwizard-client:${dropwizardVersion}"
    compile 'com.google.inject:guice:3.0'
 
    compile "ch.qos.logback:logback-classic:$logbackVersion"
    compile "ch.qos.logback:logback-core:$logbackVersion"

    testCompile 'junit:junit:4.11'
    testCompile 'org.mockito:mockito-all:1.10.8'
 }


jar {
    manifest {
        attributes 'Main-Class': "${mainClass}"
        attributes 'Built-Date': new Date() //now
        attributes 'Built-By': System.getProperty('user.name')
        attributes 'Build-Jdk': System.getProperty('java.version')
        attributes 'Implementation-Title': "${applicationName}"
        attributes 'Implementation-Version': "${applicationVersion}"
        attributes 'Implementation-Vendor-Id': "${applicationGroup}"
    }
}