-
Notifications
You must be signed in to change notification settings - Fork 9
/
Copy pathNM_Main.ipf
5882 lines (4004 loc) · 143 KB
/
NM_Main.ipf
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
527
528
529
530
531
532
533
534
535
536
537
538
539
540
541
542
543
544
545
546
547
548
549
550
551
552
553
554
555
556
557
558
559
560
561
562
563
564
565
566
567
568
569
570
571
572
573
574
575
576
577
578
579
580
581
582
583
584
585
586
587
588
589
590
591
592
593
594
595
596
597
598
599
600
601
602
603
604
605
606
607
608
609
610
611
612
613
614
615
616
617
618
619
620
621
622
623
624
625
626
627
628
629
630
631
632
633
634
635
636
637
638
639
640
641
642
643
644
645
646
647
648
649
650
651
652
653
654
655
656
657
658
659
660
661
662
663
664
665
666
667
668
669
670
671
672
673
674
675
676
677
678
679
680
681
682
683
684
685
686
687
688
689
690
691
692
693
694
695
696
697
698
699
700
701
702
703
704
705
706
707
708
709
710
711
712
713
714
715
716
717
718
719
720
721
722
723
724
725
726
727
728
729
730
731
732
733
734
735
736
737
738
739
740
741
742
743
744
745
746
747
748
749
750
751
752
753
754
755
756
757
758
759
760
761
762
763
764
765
766
767
768
769
770
771
772
773
774
775
776
777
778
779
780
781
782
783
784
785
786
787
788
789
790
791
792
793
794
795
796
797
798
799
800
801
802
803
804
805
806
807
808
809
810
811
812
813
814
815
816
817
818
819
820
821
822
823
824
825
826
827
828
829
830
831
832
833
834
835
836
837
838
839
840
841
842
843
844
845
846
847
848
849
850
851
852
853
854
855
856
857
858
859
860
861
862
863
864
865
866
867
868
869
870
871
872
873
874
875
876
877
878
879
880
881
882
883
884
885
886
887
888
889
890
891
892
893
894
895
896
897
898
899
900
901
902
903
904
905
906
907
908
909
910
911
912
913
914
915
916
917
918
919
920
921
922
923
924
925
926
927
928
929
930
931
932
933
934
935
936
937
938
939
940
941
942
943
944
945
946
947
948
949
950
951
952
953
954
955
956
957
958
959
960
961
962
963
964
965
966
967
968
969
970
971
972
973
974
975
976
977
978
979
980
981
982
983
984
985
986
987
988
989
990
991
992
993
994
995
996
997
998
999
1000
#pragma rtGlobals=3 // Use modern global access method and strict wave access.
#pragma version = 3.0
#pragma hide = 1
#pragma IgorVersion = 6.3
//****************************************************************
//****************************************************************
//
// NeuroMatic: data aquisition, analyses and simulation software that runs with the Igor Pro environment
// Copyright (C) 2019 Jason Rothman
//
// This program is free software: you can redistribute it and/or modify
// it under the terms of the GNU General Public License as published by
// the Free Software Foundation, either version 3 of the License, or
// (at your option) any later version.
//
// This program is distributed in the hope that it will be useful,
// but WITHOUT ANY WARRANTY; without even the implied warranty of
// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
// GNU General Public License for more details.
//
// You should have received a copy of the GNU General Public License
// along with this program. If not, see <https://www.gnu.org/licenses/>.
//
// Contact Jason@ThinkRandom.com
// http://www.neuromatic.thinkrandom.com
// https://github.com/SilverLabUCL/NeuroMatic
//
//****************************************************************
//****************************************************************
//
// Main Functions
//
// Set and Get functions:
//
// NMSet( [ on, tab, folder, wavePrefix, wavePrefixNoPrompt, PrefixSelectPrompt, OrderWavesBy, waveNum, waveInc, chanSelect, waveSelect, xProgress, yProgress, winCascade, configsDisplay, errorPointsLimit, openPath, savePath, history ] )
// NMConfigVarSet( "NM" , varName, value )
// NMConfigStrSet( "NM", strVarName, strValue )
// NMVarGet( varName )
// NMStrGet( strVarName )
//
// Useful Functions:
//
// NMTabAdd( tabName, tabprefix [ history ] )
// NMTabRemove( tabName [ history ] )
// NMTabKill( tabName [ history ] )
//
//****************************************************************
//****************************************************************
StrConstant NMPackage = "NeuroMatic"
StrConstant NMVersionStr = "3.0s"
Static StrConstant NMHTTP = "http://www.neuromatic.thinkrandom.com/"
Static StrConstant NMRights = "Copyright (c) 2024 The Silver Lab, UCL"
Static StrConstant NMEmail = "Jason@ThinkRandom.com"
Static StrConstant NMUCL = "UCL Neuroscience, Physiology and Pharmacology Department, London, UK"
StrConstant NMDF = "root:Packages:NeuroMatic:"
StrConstant NMClampDF = "root:Packages:NeuroMatic:Clamp:"
StrConstant NMWavePrefixList = "Record;Wave;NMWave;Avg_;Pulse_;ST_;SP_;EV_;Fit_;Histo_;Sort_;Sim_;ROI;"
StrConstant NMXscalePrefix = "xScale_"
StrConstant NMTabList = "Main;Stats;Spike;Event;Fit;"
StrConstant NMRedStr = "52224,0,0"
StrConstant NMGreenStr = "0,39168,0"
StrConstant NMBlueStr = "0,0,65535"
StrConstant NMWinColor = "51000,51000,51000" // background color of panel and graphs
//StrConstant NMWinColor2 = "47616,53760,59904" // highlight color of panel and graphs
StrConstant NMWinColor2 = "47360,40960,40704" // highlight color of panel and graphs
//StrConstant NMWinColor2 = "59904,40448,0" // highlight color of panel and graphs
//StrConstant NMWinColor2 = "16384,32768,32768" // highlight color of panel and graphs
Static Constant NMAutoStart = 1 // auto start NM ( 0 ) no ( 1 ) yes
Static Constant NMHideProcedureFiles = 1
Static Constant MakeNMPanelOnFolderChange = 0
// JSR: this parameter is for a bug fix, when set to 1. cannot remember what bug is. however this fix causes annoying flashing of NM panel.
// 7 Aug 2019, setting to 0. perhaps with latest Igor version this is not necessary.
Static Constant NMPanelResolution = 72 // for Windows OS // NM Panel was designed for 72 panel resolution
// NM uses this parameter to execute the following Igor command: SetIgorOption PanelResolution = <resolution>
// 0: Coordinates and sizes are treated as points regardless of the screen resolution.
// 1: Coordinates and sizes are treated as pixels if the screen resolution is 96 DPI, points otherwise. This is the default setting in effect when Igor starts.
// 72: Coordinates and sizes are treated as pixels regardless of the screen resolution (Igor6 mode).
Constant NMBaselineXbgn = 0 // default x-scale baseline window begin
Constant NMBaselineXend = 10 // default x-scale baseline window end
StrConstant NMXunits = "ms"
Constant NMPrefixFolderHistory = 0 // ( 0 ) do not include ( 1 ) include current prefix folder name in command history
Static Constant NMErrorPointsLimit = 200 // default value
Static Constant NMCascadeWidthPC = 425 // window width for PCs
Static Constant NMCascadeHeightPC = 275 // window height for PCs
Static Constant NMCascadeWidthMac = 525 // window width for Macs
Static Constant NMCascadeHeightMac = 340 // window height for Macs
Static Constant NMCascadeIncPC = 15 // window cascade increment PCs
Static Constant NMCascadeIncMac = 28 // window cascade increment Macs
Static Constant NMKillWinNoDialog = 1 // kill window ( 0 ) with dialog ( 1 ) without dialog
Static Constant NMHistogramPaddingBins = 4 // extra bins on each side of histogram ( auto bin sizing )
Static Constant ConfigsEditByPrompt = 1 // edit configs ( 0 ) directly via listbox ( 1 ) by user prompts
Static StrConstant NMDeprecationIPF = "NM_Deprecated.ipf"
//****************************************************************
//****************************************************************
Function NMVersionNum()
String versionStr = NMVersionStr
Variable ilength = strlen( versionStr )
String numStr = versionStr[ 0, ilength-2 ]
String suffix = num2istr( char2num( versionStr[ ilength-1, ilength-1 ] ) ) // convert last character to ascii code
return str2num( numStr + suffix )
End // NMVersionNum
//****************************************************************
//****************************************************************
Function NMWebpage()
BrowseURL /Z NMHTTP
End // NMWebpage
//****************************************************************
//****************************************************************
Function NMContact()
Print "Send email inquiries to " + NMEmail
DoAlert 0, "Send email inquiries to " + NMEmail
End // NMContact
//****************************************************************
//****************************************************************
Function /S NMversion( [ short ] )
Variable short
if ( short )
return "NeuroMatic v" + NMVersionStr
else
return "NeuroMatic version " + NMVersionStr + " (" + num2str( NMVersionNum() ) + ")"
endif
End // NMversion
//****************************************************************
//****************************************************************
Function NMAbout()
NMHistory( NMCR )
NMHistory( NMversion( short=1 ) + " " + NMRights )
//NMHistory( NMUCL )
NMHistory( NMEmail )
NMHistory( NMHTTP )
NMHistory( NMCR )
NMGNUGPL()
NMHistory( NMCR )
NMCitation()
//NMWarranty()
//DoAlert 0, version
End // NMAbout
//****************************************************************
//****************************************************************
Function NMGNUGPL()
NMHistory( "This program comes with ABSOLUTELY NO WARRANTY. This is free software, " )
NMHistory( "and you are welcome to redistribute it under certain conditions." )
NMHistory( "For more information see LICENSE.txt inside NeuroMatic's procedure folder." )
End // NMGNUGPL
//****************************************************************
//****************************************************************
Function NMWarranty()
NMHistory( "THERE IS NO WARRANTY FOR THE PROGRAM, TO THE EXTENT PERMITTED BY" )
NMHistory( "APPLICABLE LAW. EXCEPT WHEN OTHERWISE STATED IN WRITING THE COPYRIGHT" )
NMHistory( "HOLDERS AND/OR OTHER PARTIES PROVIDE THE PROGRAM " + NMQuotes( "AS IS" ) + " WITHOUT WARRANTY" )
NMHistory( "OF ANY KIND, EITHER EXPRESSED OR IMPLIED, INCLUDING, BUT NOT LIMITED TO," )
NMHistory( "THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR" )
NMHistory( "PURPOSE. THE ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE PROGRAM" )
NMHistory( "IS WITH YOU. SHOULD THE PROGRAM PROVE DEFECTIVE, YOU ASSUME THE COST OF" )
NMHistory( "ALL NECESSARY SERVICING, REPAIR OR CORRECTION." )
End // NMWarranty
//****************************************************************
//****************************************************************
Function NMCitation()
NMHistory( "Please support NeuroMatic by citing the following Frontiers article:" )
NMHistory( "Rothman JS and Silver RA." )
NMHistory( "NeuroMatic: An Integrated Open-Source Software Toolkit for Acquisition, Analysis and Simulation of Electrophysiological Data." )
NMHistory( "Front Neuroinform. 2018 Apr 4;12:14." )
NMHistory( "https://doi.org/10.3389/fninf.2018.00014" )
End // NMCitation
//****************************************************************
//****************************************************************
//
// Package Functions
//
//****************************************************************
//****************************************************************
Function /S NMPackageDF( subfolderName )
String subfolderName
if ( StringMatch( subfolderName, NMPackage ) )
return NMDF
endif
return LastPathColon( NMDF + subfolderName, 1 )
End // NMPackageDF
//****************************************************************
//****************************************************************
Function CheckNMPackageDF( subfolderName ) // check Package data folder exists
String subfolderName // subfolder
if ( !DataFolderExists( "root:Packages:" ) )
NewDataFolder root:Packages
endif
if ( !DataFolderExists( NMDF ) )
NewDataFolder $RemoveEnding( NMDF, ":" )
endif
if ( !DataFolderExists( NMDF + "Configurations:" ) )
NewDataFolder $NMDF + "Configurations"
endif
if ( ( strlen( subfolderName ) == 0 ) || StringMatch( subfolderName, NMPackage ) )
return 0
endif
if ( ( strlen( subfolderName ) > 0 ) && !DataFolderExists( NMDF + subfolderName + ":" ) )
NewDataFolder $( NMDF + subfolderName )
return 1 // yes, made the folder
endif
return 0 // did not make folder
End // CheckNMPackageDF
//****************************************************************
//****************************************************************
Function CheckNMPackage( package, forceVariableCheck [ update ] ) // check folder / globals
String package // package folder name
Variable forceVariableCheck // ( 0 ) no ( 1 ) yes
Variable update
String fxn, df = NMPackageDF( package )
Variable made = CheckNMPackageDF( package ) // check folder
if ( !made && !forceVariableCheck )
return 0
endif
if ( ParamIsDefault( update ) )
update = 1
endif
fxn = "NM" + package + "Check" // e.g. "NMStatsCheck()"
if ( exists( fxn ) != 6 )
fxn = "Check" + package // e.g. "CheckStats()"
endif
if ( exists( fxn ) == 6 )
Execute /Z fxn + "()"
endif
if ( made )
NMConfig( package, -1, update = update ) // copy configs to new folder
else
NMConfig( package, 1, update = update ) // copy folder vars to configs
endif
return made
End // CheckNMPackage
//****************************************************************
//****************************************************************
Function CheckNMPackageFormat6()
Variable icnt
String iName
String moveList = "Configurations;Event;Fit;Import;Main;MyTab;Spike;Stats;Clamp;AMPAR;EPSC;RiseT;Model;"
String deleteList = "Chan;"
String cdf = ConfigDF( "" )
for ( icnt = 0 ; icnt < ItemsInList( moveList ) ; icnt += 1 )
iName = StringFromList( icnt, moveList )
if ( DataFolderExists( "root:Packages:" + iName + ":" ) )
if ( !DataFolderExists( NMDF + iName + ":" ) )
MoveDataFolder $( "root:Packages:" + iName ), $NMDF
//Print "moved " + iName + " package folder to " + NMDF
endif
endif
endfor
for ( icnt = 0 ; icnt < ItemsInList( deleteList ) ; icnt += 1 )
iName = StringFromList( icnt, deleteList )
if ( DataFolderExists( "root:Packages:" + iName + ":" ) )
KillDataFolder /Z $"root:Packages:" + iName
endif
if ( DataFolderExists(cdf + iName + ":" ) )
KillDataFolder /Z $cdf + iName
endif
endfor
End // CheckNMPackageFormat6
//****************************************************************
//****************************************************************
Function IgorStartOrNewHook( igorApplicationNameStr )
String igorApplicationNameStr
if ( NMAutoStart )
CheckNMVersion()
endif
End // IgorStartOrNewHook
//****************************************************************
//****************************************************************
Static Function BeforeExperimentSaveHook( refNum, fileNameStr, pathNameStr, fileTypeStr, fileCreatorStr, fileKind )
Variable refNum
String fileNameStr, pathNameStr, fileTypeStr, fileCreatorStr
Variable fileKind
KillNMPaths()
if ( NMConfigsAutoOpenSave )
NMConfigsSaveToPackages()
endif
return 0
End // BeforeExperimentSaveHook
//****************************************************************
//****************************************************************
Static Function AfterFileOpenHook( refNum, fileName, path, type, creator, kind )
Variable refNum
String fileName, path, type, creator
Variable kind
if ( NMAutoStart )
CheckNMVersion()
endif
if ( StringMatch( type,"IGsU" ) ) // Igor Experiment, packed
CheckFileOpen( fileName )
endif
//MakeNMPanel()
return 0
End // AfterFileOpenHook
//****************************************************************
//****************************************************************
Static Function IgorBeforeNewHook( igorApplicationNameStr )
String igorApplicationNameStr
if ( NMConfigsAutoOpenSave )
NMConfigsSaveToPackages()
endif
End // IgorBeforeNewHook
//****************************************************************
//****************************************************************
Function CheckNMVersion()
String existingVersion = StrVarOrDefault( NMDF + "NMVersionStr", "" )
if ( !StringMatch( existingVersion, NMVersionStr ) )
return ResetNM( 0, quiet = 1, oldVersionStr = existingVersion )
endif
return 0
End // CheckNMVersion
//****************************************************************
//****************************************************************
Function ResetNM( killFirst [ quiet, history, oldVersionStr ] ) // use this function to re-initialize neuromatic
Variable killfirst // kill variables first flag
Variable history
String oldVersionStr
Variable quiet
Variable fatal, deprecations
String fList, vlist = ""
if ( history )
vlist = NMCmdNum( killFirst, "", integer = 1 )
NMCommandHistory( vlist )
endif
if ( !quiet )
DoAlert /T="NM Alert" 1, "Are you sure you want to re-initialize NM globals?"
if ( V_flag != 1 )
return 0
endif
endif
DoWindow /K $NMPanelName
CheckNMPackageFormat6()
//CheckCurrentFolder() // must set this here, otherwise Igor is at root directory // removed
NMTabControlList()
ChanGraphClose( -2, 0 ) // close all graphs
Execute /Q/Z "CheckClampTab2()" // added this so Clamp Tab is updated for new NM versions
if ( killfirst )
NMKill() // this is hard kill, and will reset previous global variables to default values
endif
if ( CheckNM() < 0 )
return -1
endif
SetNMvar( NMDF + "CurrentTab", 0 ) // set Main Tab as current tab
CheckNMDataFolders()
CheckNMFolderList()
NMChanWaveListSet( 0 )
SetNMstr( NMDF + "NMVersionStr", NMVersionStr )
SetNMstr( NMDF + "NMMenuLoad", "" )
if ( WinType( NMPanelName ) != 7 )
MakeNMPanel()
endif
CheckCurrentFolder()
if ( IsNMDataFolder( "" ) )
UpdateCurrentWave()
endif
NMProceduresHideUpdate()
NMMenuBuild()
if ( ParamIsDefault( oldVersionStr ) || ( strlen( oldVersionStr ) == 0 ) )
NMHistory( "Initialized " + NMversion( short=1 ) )
else
NMHistory( NMCR + "Updated NeuroMatic from version " + oldVersionStr + " to " + NMVersionStr )
endif
return 0
End // ResetNM
//****************************************************************
//****************************************************************
Function CheckNM()
Variable madeNMDF
String ftype
if ( !NMVarGet( "NMon" ) )
return 1
endif
if ( !DataFolderExists( NMDF ) )
madeNMDF = 1
endif
CheckNMPackageDF( "" )
if ( !DataFolderExists( NMDF ) )
return -1
endif
if ( madeNMDF )
CheckNeuroMatic()
NMConfig( NMPackage, -1, update = 0 )
else
NMConfig( NMPackage, 0, update = 0 )
endif
NMProgressOn( NMProgFlagDefault() ) // test progress window
CheckNMPaths()
CheckFileOpen( "" )
if ( madeNMDF )
if ( NMConfigsAutoOpenSave )
NMConfigsOpenFromPackages() // Igor Packages
endif
NMConfigOpenAuto() // configs saved in NM folder
CheckNMPaths()
ftype = StrVarOrDefault( "FileType", "" )
if ( StringMatch( ftype, "NMData" ) )
UpdateNM( 1 )
else
NMFolderNew( "", update = 0 )
endif
endif
CheckNMPanelResolution()
KillGlobals( "root:", "V_*", "110" ) // clean root directory
KillGlobals( "root:", "S_*", "110" )
return madeNMDF
End // CheckNM
//****************************************************************
//****************************************************************
Function UpdateNM( forceMakeNewPanel )
Variable forceMakeNewPanel
Variable isNMfolder
String ftype = StrVarOrDefault( "FileType", "" )
if ( StringMatch( ftype, "NMData" ) )
isNMfolder = 1
endif
if ( WinType( NMPanelName ) == 7 )
if ( forceMakeNewPanel && MakeNMPanelOnFolderChange )
MakeNMPanel()
else
UpdateNMPanel( 1 )
endif
else
// MakeNMPanel() // causes bug
endif
CheckCurrentFolder()
CheckNMFolderList()
NMSetsPanelUpdate( 1 )
NMGroupsPanelUpdate( 1 )
NMMenuBuild()
if ( isNMfolder )
UpdateCurrentWave()
endif
End // UpdateNM
//****************************************************************
//****************************************************************
Function NMKill( [ quiet ] ) // use this with caution!
Variable quiet
String df
if ( !quiet )
DoAlert /T="NM Alert" 1, "Are you sure you want to kill NeuroMatic from the current experiment?"
if ( V_flag != 1 )
return 0
endif
endif
DoWindow /K $NMPanelName
KillTabs( NMTabControlList() ) // kill tab plots, tables and globals
ChanGraphClose( -2, 0 ) // close all graphs
if ( DataFolderExists( NMDF ) )
KillDataFolder $NMDF
endif
//NMProceduresKill( quiet = 1 )
End // NMKill
//****************************************************************
//****************************************************************
Function NMProceduresHideUpdate()
if ( NMHideProcedureFiles )
Execute /Q/Z "SetIgorOption IndependentModuleDev = 0"
else
Execute /Q/Z "SetIgorOption IndependentModuleDev = 1" // unhide procedures
endif
End // NMProceduresHideUpdate
//****************************************************************
//****************************************************************
Function NMProceduresHide( hide )
Variable hide // ( 0 ) no ( 1 ) yes
if ( hide )
NMHistory( "SetIgorOption IndependentModuleDev = 0" )
Execute /Q/Z "SetIgorOption IndependentModuleDev = 0"
else
NMMenuProceduresList( "misc", update = 1 ) // update lists of procedure names
NMHistory( "SetIgorOption IndependentModuleDev = 1" )
Execute /Q/Z "SetIgorOption IndependentModuleDev = 1" // unhide
endif
NMMenuBuild()
End // NMProceduresHide
//****************************************************************
//****************************************************************
Function /S NMProceduresList()
String pList
Execute /Z "SetIgorOption IndependentModuleDev = ?"
Variable saveIMD = NumVarOrDefault( "V_Flag", NaN )
Execute /Q/Z "SetIgorOption IndependentModuleDev = 1" // unhide procedures
pList = SortList( WinList( "NM_*", ";", "WIN:128" ), ";", 16 ) // all procedures
Execute /Z "SetIgorOption IndependentModuleDev = " + num2istr( saveIMD )
return pList
End // NMProceduresList
//****************************************************************
//****************************************************************
Function NMProceduresKill( [ quiet ] )
Variable quiet
Variable icnt
String windowList, windowName
if ( !quiet )
DoAlert /T="NM Alert" 1, "Are you sure you want to kill all NeuroMatic procedure files from the current experiment?"
if ( V_flag != 1 )
return 0
endif
endif
Execute /Q/Z "SetIgorOption IndependentModuleDev = 1" // unhide procedures
windowList = NMProceduresList()
for ( icnt = 0 ; icnt < ItemsInList( windowList ) ; icnt += 1 )
windowName = StringFromList( icnt, windowList )
Execute /P/Q/Z "CloseProc /NAME=" + NMQuotes( windowName ) + " /COMP=0 /D=0"
windowName = ReplaceString( ".ipf", windowName, "" )
Execute /P/Q/Z "DELETEINCLUDE \"" + windowName + "\""
endfor
Execute/P/Q/Z "COMPILEPROCEDURES " // Note the space before final quote
DoWindow /K $NMPanelName
End // NMProceduresKill
//****************************************************************
//****************************************************************
//
// NeuroMatic Global Functions
//
//****************************************************************
//****************************************************************
Function CheckNeuroMatic() // check main NeuroMatic globals
CheckNMtwave( NMDF + "FolderList", 0, "" ) // wave of NM folder names
End // CheckNeuroMatic
//****************************************************************
//****************************************************************
Function NMSet( [ on, tab, folder, wavePrefix, wavePrefixNoPrompt, PrefixSelectPrompt, OrderWavesBy, waveNum, waveInc, chanSelect, waveSelect, xProgress, yProgress, winCascade, configsDisplay, errorPointsLimit, openPath, savePath, prefixFolder, history ] )
Variable on
String tab
String folder
String wavePrefix, wavePrefixNoPrompt
Variable PrefixSelectPrompt // config variable
String OrderWavesBy // config string
Variable waveNum, waveInc
String chanSelect, waveSelect
Variable xProgress, yProgress // config variables
Variable winCascade
Variable configsDisplay
Variable errorPointsLimit
String openPath, savePath
String prefixFolder // used with waveNum, chanSelect, waveSelect
Variable history // print function command to history ( 0 ) no ( 1 ) yes
String vlist = "", vlist2 = ""
if ( ParamIsDefault( prefixFolder ) )
prefixFolder = CurrentNMPrefixFolder()
else
if ( strlen( prefixFolder ) > 0 )
vlist2 = NMCmdStrOptional( "prefixFolder", prefixFolder, vlist2 )
elseif ( NMPrefixFolderHistory && ( strlen( prefixFolder ) == 0 ) )
prefixFolder = CurrentNMPrefixFolder()
vlist2 = NMCmdStrOptional( "prefixFolder", prefixFolder, vlist2 )
endif
prefixFolder = CheckNMPrefixFolderPath( prefixFolder )
endif
if ( !ParamIsDefault( on ) )
vlist = NMCmdNumOptional( "on", on, vlist, integer = 1 )
NMon( BinaryCheck( on ) )
endif
if ( !ParamIsDefault( tab ) )
vlist = NMCmdStrOptional( "tab", tab, vlist )
NMTab( tab )
endif
if ( !ParamIsDefault( folder ) )
vlist = NMCmdStrOptional( "folder", folder, vlist )
if ( IsNMFolder( folder, "NMLog" ) )
folder = CheckNMFolderPath( folder )
LogDisplayCall( folder )
elseif ( IsNMFolder( folder,"NMData" ) )
NMFolderChange( folder )
else
NMFolderNew( folder )
endif
endif
if ( !ParamIsDefault( wavePrefix ) )
vlist = NMCmdStrOptional( "wavePrefix", wavePrefix, vlist )
if ( NMVarGet( "PrefixSelectPrompt" ) )
NMPrefixSelect( wavePrefix )
else
NMPrefixSelect( wavePrefix, noPrompts = 1 )
endif
endif
if ( !ParamIsDefault( wavePrefixNoPrompt ) )
vlist = NMCmdStrOptional( "wavePrefixNoPrompt", wavePrefixNoPrompt, vlist )
NMPrefixSelect( wavePrefixNoPrompt, noPrompts = 1 )
endif
if ( !ParamIsDefault( PrefixSelectPrompt ) )
vlist = NMCmdNumOptional( "PrefixSelectPrompt", PrefixSelectPrompt, vlist )
NMConfigVarSet( "NM" , "PrefixSelectPrompt" , BinaryCheck( PrefixSelectPrompt ) )
endif
if ( !ParamIsDefault( OrderWavesBy ) )
vlist = NMCmdStrOptional( "OrderWavesBy", OrderWavesBy, vlist )
if ( !StringMatch( OrderWavesBy, "date" ) )
OrderWavesBy = "name"
endif
NMConfigStrSet( "NM" , "OrderWavesBy" , OrderWavesBy )
endif
if ( !ParamIsDefault( waveNum ) )
vlist = NMCmdNumOptional( "waveNum", waveNum, vlist, integer = 1 )
NMCurrentWaveSet( waveNum, prefixFolder = prefixFolder )
endif
if ( !ParamIsDefault( waveInc ) )
vlist = NMCmdNumOptional( "waveInc", waveInc, vlist, integer = 1 )
NMWaveInc( waveInc )
endif
if ( !ParamIsDefault( chanSelect ) )
vlist = NMCmdStrOptional( "chanSelect", chanSelect, vlist )
NMChanSelect( chanSelect, prefixFolder = prefixFolder )
endif
if ( !ParamIsDefault( waveSelect ) )
vlist = NMCmdStrOptional( "waveSelect", waveSelect, vlist )
NMWaveSelect( waveSelect, prefixFolder = prefixFolder )
endif
if ( !ParamIsDefault( xProgress ) )
vlist = NMCmdNumOptional( "xProgress", xProgress, vlist )
if ( ( numtype( xProgress ) > 0 ) || ( xProgress < 0 ) )
xProgress = NaN
endif
SetNMvar( NMDF + "xProgress", xProgress )
NMConfigVarSet( "NeuroMatic", "xProgress", xProgress )
endif
if ( !ParamIsDefault( yProgress ) )
vlist = NMCmdNumOptional( "yProgress", yProgress, vlist )
if ( ( numtype( yProgress ) > 0 ) || ( yProgress < 0 ) )
yProgress = NaN
endif
SetNMvar( NMDF + "yProgress", yProgress )
NMConfigVarSet( "NeuroMatic", "yProgress", yProgress )
endif
if ( !ParamIsDefault( winCascade ) )
vlist = NMCmdNumOptional( "winCascade", winCascade, vlist, integer = 1 )
if ( ( numtype( winCascade ) > 0 ) || ( winCascade < 0 ) )
winCascade = 0
endif
SetNMvar( NMDF + "Cascade", floor( winCascade ) )
endif
if ( !ParamIsDefault( configsDisplay ) )
vlist = NMCmdNumOptional( "configsDisplay", configsDisplay, vlist )
NMConfigsDisplay( BinaryCheck( configsDisplay ) )
endif
if ( !ParamIsDefault( errorPointsLimit ) )
vlist = NMCmdNumOptional( "errorPointsLimit", errorPointsLimit, vlist, integer = 1 )
if ( errorPointsLimit >= 0 )
NMConfigVarSet( "NM" , "ErrorPointsLimit" , errorPointsLimit )
endif
endif
if ( !ParamIsDefault( openPath ) )
vlist = NMCmdStrOptional( "openPath", openPath, vlist )
NewPath /Q/O/M="Set Open File Path" OpenDataPath, openPath
if ( V_flag == 0 )
NMConfigStrSet( "NM", "OpenDataPath", openPath )
endif
endif
if ( !ParamIsDefault( savePath ) )
vlist = NMCmdStrOptional( "savePath", savePath, vlist )
NewPath /Q/O/M="Set Save File Path" SaveDataPath, savePath
if ( V_flag == 0 )
NMConfigStrSet( "NM", "SaveDataPath", savePath )
endif
endif
if ( history )
NMCommandHistory( vlist + vlist2 )
endif
End // NMSet
//****************************************************************
//****************************************************************
Function NMVarGet( varName )
String varName
Variable defaultVal = Nan
String thisfxn = GetRTStackInfo( 1 )
strswitch( varName )
case "AlertUser":