From 6efca77611d4b48f3e089e07240cdcbc8f07ea0d Mon Sep 17 00:00:00 2001
From: oddlama <oddlama@oddlama.org>
Date: Tue, 25 Jul 2023 14:08:42 +0200
Subject: [PATCH] meson64-tools: init at b09cefd1

---
 pkgs/misc/meson64-tools/default.nix | 45 +++++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix     |  1 +
 2 files changed, 46 insertions(+)
 create mode 100644 pkgs/misc/meson64-tools/default.nix

diff --git a/pkgs/misc/meson64-tools/default.nix b/pkgs/misc/meson64-tools/default.nix
new file mode 100644
index 00000000000000..c5ce2d998ecd12
--- /dev/null
+++ b/pkgs/misc/meson64-tools/default.nix
@@ -0,0 +1,45 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, buildPackages
+}:
+
+stdenv.mkDerivation rec {
+  pname = "meson64-tools";
+  version = "unstable-2023-07-25";
+
+  src = fetchFromGitHub {
+    owner = "angerman";
+    repo = pname;
+    rev = "b09cefd1e001dbba14036857bf6e167bf1833f26";
+    hash = "sha256-/koIsslDNpaFHf1TV/0Xt0TiyhjL6tCz2oHQraYNhPA=";
+  };
+
+  nativeBuildInputs = with buildPackages; [ openssl bison yacc flex bc python3 ];
+
+  preBuild = ''
+    patchShebangs --build .
+    patchShebangs --build ./mbedtls/scripts/generate_psa_constants.py
+    substituteInPlace mbedtls/programs/fuzz/Makefile --replace "python2" "python"
+    substituteInPlace mbedtls/tests/Makefile --replace "python2" "python"
+  '';
+
+  # Also prefix tool names since some names are really generic (e.g. `pkg`).
+  # Otherwise something could shadow those generic names in other builds.
+  postInstall = ''
+    (cd $out/bin
+      for bin in *; do
+        ln -s $bin meson64-$bin
+      done
+    )
+  '';
+
+  makeFlags = [ "PREFIX=$(out)/bin" ];
+
+  meta = with lib; {
+    homepage = "https://github.com/angerman/meson64-tools";
+    description = "Tools for Amlogic Meson ARM64 platforms";
+    license = licenses.mit;
+    maintainers = with maintainers; [ oddlama ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index f396085da5adbd..4d44406874624b 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -5782,6 +5782,7 @@ with pkgs;
         } ../development/tools/build-managers/meson/emulator-hook.sh
     else throw "mesonEmulatorHook has to be in a conditional to check if the target binaries can be executed i.e. (!stdenv.buildPlatform.canExecute stdenv.hostPlatform)";
 
+  meson64-tools = callPackage ../misc/meson64-tools { };
   meson-tools = callPackage ../misc/meson-tools { };
 
   metabase = callPackage ../servers/metabase {