build.gradle

plugins {
	id 'fabric-loom' version '1.7-SNAPSHOT'
	id 'maven-publish'
	id 'org.ysb33r.ivypot' version '2.0.2'
}

sourceCompatibility = JavaVersion.VERSION_17
targetCompatibility = JavaVersion.VERSION_17

archivesBaseName = project.archives_base_name
version = "${project.mod_version}+${project.minecraft_version}"
group = project.maven_group

ivypot {
	repoDetails {
		root = '.offline-repo'
	}
}

repositories {
	maven {
		name = 'minecraft-repo'
		url = 'https://libraries.minecraft.net/'
	}
	maven { url "https://api.modrinth.com/maven" }
	maven { url = 'https://maven.terraformersmc.com/' }
	maven { url = "https://maven.maxhenkel.de/repository/public" } // Simple Voice Chat
	maven { url = "https://mvn.devos.one/snapshots/" } // Create Fabric, Porting Lib, Forge Tags, Milk Lib, Registrate Fabric
	maven { url = "https://maven.jamieswhiteshirt.com/libs-release" } // Reach Entity Attributes
	maven { // Flywheel, Registrate, Create
		url = "https://maven.tterrag.com/"
		content {
			includeGroup("com.simibubi.create")
			includeGroup("com.tterrag.registrate")
			includeGroup("com.jozufozu.flywheel")
		}
	}
	maven { // YACL
		name 'Xander Maven'
		url 'https://maven.isxander.dev/releases'
	}
	maven {
		url 'https://repo.sleeping.town'
		content {
			includeGroup 'com.unascribed'
		}
	}
	flatDir name: 'local_libs', dirs: "$projectDir/local_repo"
}

dependencies {
	minecraft "com.mojang:minecraft:${project.minecraft_version}"
	mappings "net.fabricmc:yarn:${project.yarn_mappings}:v2"
	modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"

	modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

	modImplementation "maven.modrinth:jsonem:${project.jsonem_version}"
	include "maven.modrinth:jsonem:${project.jsonem_version}"

	modApi("com.terraformersmc:modmenu:${project.modmenu_version}") { transitive false }

	modImplementation "dev.isxander:yet-another-config-lib:${project.yacl_version}"

	//modCompileOnly("de.maxhenkel.voicechat:voicechat-api:${project.voicechat_api_version}")
	modCompileOnly("maven.modrinth:simple-voice-chat:fabric-${project.voicechat_version}")

	if (project.enable_simple_voice_chat.toBoolean()) {
		modLocalRuntime("maven.modrinth:simple-voice-chat:fabric-${project.voicechat_version}")
	}

	if (project.enable_create.toBoolean()) {
		// Create - dependencies are added transitively
		modLocalRuntime("com.simibubi.create:create-fabric-${project.minecraft_version}:${project.create_fabric_version}")
	}

	if (project.enable_music_disc_mods.toBoolean()) {
		modLocalRuntime("maven.modrinth:more-music-discs:${project.more_music_discs_version}") { transitive = false }
		modLocalRuntime("maven.modrinth:spindlemark:${project.spindlemark_version}") { transitive = false }
		modLocalRuntime("com.unascribed:lib39-core:${project.lib39_version}")
		modLocalRuntime("com.unascribed:lib39-keygen:${project.lib39_version}")
	}
}

processResources {
	inputs.property "version", project.version

	filesMatching("fabric.mod.json") {
		expand(
				"version": project.version,
				"fabric_loader_version": project.loader_version,
				"fabric_api_version": project.fabric_version,
				"yacl_version": project.yacl_version,
		)
	}
}

tasks.withType(JavaCompile) {
	options.encoding = "UTF-8"
}

java {
	withSourcesJar()
}

jar {
	from "LICENSE"
}

loom {
	accessWidenerPath = file("src/main/resources/phonos.accesswidener")
}

publishing {
	publications {
		mavenJava(MavenPublication) {
			artifact(remapJar) {
				builtBy remapJar
			}
			artifact(sourcesJar) {
				builtBy remapSourcesJar
			}
		}
	}

	repositories {
		// mavenLocal()
	}
}