Set and flashing default credentials

[SmartVolt]

Hi, and thank you for this great project!
I want to use this library for my tutorials, but how can i flash default wifi credentials ? Something like this:

const char* initialSsid = "yourNetworkName";
const char* initialPassword =  "yourNetworkPass";

void setup() {
 
  Serial.begin(115200);
 
  WiFi.begin(initialSsid, initialPassword);

 // ?????
  if (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.println("Setting Access Point Mode beceause initial credentials are wrong..");
     // ?????
  }
 
}

[Hieromon]

You can use the AutoConnect::onDetect function to see if the access point started because AutoConnect::begin with the default credentials failed.
More information for the onDetect API can be found in Captive portal start detection section of the documentation.

#include <Arduino.h>
#include <WiFi.h>       // For ESP8266, needs to change to ESP8266WiFi.h
#include <WebServer.h>  // For ESP8266, needs to change to ESP8266WebServer.h
#include <AutoConnect.h>

const char* initialSsid = "yourNetworkName";
const char* initialPassword =  "yourNetworkPass";

AutoConnect portal;

// Callback function at an AP start
bool startAP(IPAddress& ip) {
  Serial.println("Setting Access Point Mode because initial credential is wrong..");
  Serial.println("AP started, IP:" + ip.toString());
  return true;
}

void setup() {
  delay(1000);
  Serial.begin(115200);
  Serial.println();

  portal.onDetect(startAP);  // When the AP start is detected, the startCP function is executed.
  portal.begin(initialSsid, initialPassword);  // Specify the default SSID and password. If the default value does not match the AP you wish, the access point will start.
}

void loop() {
  portal.handleClient();
}

NOTE:
The onDetetct callback is not executed when AutoConnectConfig::autoRise is false.